Grammar for rewards (May 1998)

Non-terminals will be denoted by upper-case letters and terminal symbols by lower-case letters. empty denotes the empty string. A reward specification is a list of rewards.


REWARD ::= 
    \begin{reward}
      RATE_REWARD | IMPULSE_REWARD
    \end{reward} REWARD 
  | empty

RATE_REWARD ::= 
    \begin{rate_reward} \name{NAME}
      \measure{R-MEASURE} \correspond{ID}
      \condition{CONDITION-EXPR}
      \value{VALUE-EXPR}
    \end{rate_reward}
  | empty

IMPULSE_REWARD ::= 
    \begin{impulse_reward} \name{NAME}
      \measure{R-MEASURE} \correspond{ID}
      \pre_condition{CONDITION-EXPR}
      \post_condition{CONDITION-EXPR}
      \value{VALUE-EXPR}
    \end{impulse_reward}
  | empty

NAME   ::= STRING

R-MEASURE ::= R-TYPE stationary_measure | 
              R-TYPE \transient_measure{CONSTANT} | 
              R-TYPE \accumulated_measure{CONSTANT CONSTANT}

R-TYPE ::= mean | variance | distribution



CONDITION-EXPR ::= TRUE | FALSE
  | COMPARE-EXPR
  | (BOOL-OPER-UNARY CONDITION-EXPR)
  | (CONDITION-EXPR BOOL-OPER-BINARY 
    CONDITION-EXPR)

BOOL-OPER-UNARY ::= !     

BOOL-OPER-BINARY ::= && | ||   

COMPARE-EXPR ::= 
    (VALUE-EXPR COMPARE-OPER VALUE-EXPR)

COMPARE-OPER ::= > | >= | < | <= | == | !=



VALUE-EXPR ::= CONSTANT | PRE_POST_ID
  | (ARITH-OPER-UNARY VALUE-EXPR)
  | (VALUE-EXPR ARITH-OPER-BINARY VALUE-EXPR)

PRE_POST_ID ::= ID | pre.ID | post.ID

ARITH-OPER-UNARY  ::= + | -

ARITH-OPER-BINARY ::= + | - | * | / | %




ID ::= ORDINARY-PLACE.COLOUR
  | QUEUEING-PLACE.queue.COLOUR
  | QUEUEING-PLACE.queue.mean.COLOUR
  | QUEUEING-PLACE.depository.COLOUR
  | SUBNET-PLACE.input.COLOUR
  | SUBNET-PLACE.output.COLOUR
  | SUBNET-PLACE.actual_population.COLOUR
  | SUBNET-PLACE.subnet.ID
  | TRANSITION.COLOUR
  | TRANSITION.weight.COLOUR
  | incidence((PLACE,COLOUR),
    (TRANSITION,COLOUR))

Falko Bause, Peter Buchholz, Peter Kemper
LS Informatik IV , Universität Dortmund